<!-- #include file="adovbs.inc" -->
<!-- #include file="XcIBLib.asp" -->
<%
'***********************************************************************
'******* XcInfoBase Copyright 2000 XCENT    www.xcent.com **************
'***********************************************************************
   sCMD = UCase(Trim(RequestValue("CMD")))
   sName = Trim(RequestValue("NAME"))
   sEmail = Trim(RequestValue("EMAIL"))
   sTitle = Trim(RequestValue("TITLE"))
   sCategory = Trim(RequestValue("CATEGORY"))
   If Left(sCategory,1) = "*" Then
      sCategory = ""
   End If
   sMessage = Trim(RequestValue("MESSAGE"))
   sErr = ""
   
   Select Case sCMD
      Case "ADD":
         If Len(sName) = 0 Then
            sErr = sErr & "Your Name is required. "
         End If
         If Len(sEmail) = 0 Then
            sErr = sErr & "Your Email address is required. "
         End If
         If Len(sTitle) = 0 Then
            sErr = sErr & "A Title is required. "
         End If
         If FVal(sCategory) = 0 Then
            sErr = sErr & "You must choose a Category. "
         End If
         If Len(sMessage) = 0 Then
            sErr = sErr & "You did not ask a question. "
         End If
         If Len(Trim(sErr)) = 0 Then
            SendForm
         Else
            AddForm
         End If
      Case Else
         AddForm
   End Select


Sub SendForm
	vCreated = Now
	OpenDBConn
   sSQL = "INSERT INTO tblIBInfoBase (basCatID, basCreated, basLastUpdated, basAvailable, basAdminNotify, basTitle, basBody, basAskByName, basAskByEmail) " & _
            "VALUES (" & _
            SQLVal( RequestValue("CATEGORY") ) & ", " & _
            SQLDate( vCreated ) & ", " & _
            SQLDate( vCreated ) & ", " & _
            SQLStr("N") & ", " & _
            SQLStr("N") & ", " & _
			SQLStr( RequestValue("TITLE") ) & ", " & _
            SQLStr( RequestValue("MESSAGE") ) & ", " & _
            SQLStr( RequestValue("NAME") ) & ", " & _
            SQLStr( RequestValue("EMAIL") ) & ") "
   gobjConn.Execute sSQL
   
   sSQL = "SELECT basID FROM tblIBInfoBase WHERE basCreated = " & SQLDate(vCreated) & _
               " AND basLastUpdated = " & SQLDate(vCreated) & _
               " AND basTitle = " & SQLStr(RequestValue("TITLE") ) & _
               " AND basAskByEmail = " & SQLStr( RequestValue("EMAIL") )
   lID = 0
   Set rs = gobjConn.Execute(sSQL)
   If Not rs.Eof Then
      lID = FVal(rs.Fields("basID"))
   End If
   rs.Close
   Set rs = Nothing

   iSelected = False
   If giPickSelectee Then
      sSQL = "SELECT masValue FROM tblIBMaster WHERE masParameter = 'SELECTEE'"
      Set rs = gobjConn.Execute(sSQL)
      If Not rs.Eof Then
         iSelecteeCount = FVal(rs.Fields("masValue"))
         If iSelecteeCount = 0 Then
            iSelected = True
            If giRandomizeSelectee Then
               Randomize
               sSQL = "UPDATE tblIBMaster SET masValue = " & SQLStr(CInt((rnd*giSelecteeCount)+(giSelecteeCount/2))) & " WHERE masParameter = 'SELECTEE'"
               gobjConn.Execute sSQL
            Else
               sSQL = "UPDATE tblIBMaster SET masValue = " & SQLStr(giSelecteeCount) & " WHERE masParameter = 'SELECTEE'"
               gobjConn.Execute sSQL
            End If
         Else
            iSelecteeCount = iSelecteeCount - 1
            sSQL = "UPDATE tblIBMaster SET masValue = " & SQLStr(iSelecteeCount) & " WHERE masParameter = 'SELECTEE'"
            gobjConn.Execute sSQL
         End If
      End If
      rs.Close
      Set rs = Nothing
   End If

   If giNotifyAdminNewEntries Then
      sSQL = "SELECT masValue FROM tblIBMaster WHERE masParameter = 'ADMINNOTICE'"
      Set rsAN = gobjConn.Execute(sSQL) 
      If Not rsAN.Eof Then
         'Notice already sent
      Else
         sSQL = "INSERT INTO tblIBMaster (masParameter, masValue) VALUES ('ADMINNOTICE', 'Y')"
         gobjConn.Execute sSQL
         SendEmailMessage gsAdminEmail, gsAdminEmail, "New " & gsInfoBaseName & " Item Posted", "At least one new item has been posted in the database."
      End If
      rsAN.Close
      Set rsAN = Nothing
   End If

   If iSelected Then
      vCreated = Now
      sSQL = "INSERT INTO tblIBSelectees (selEmail, selName, selDate, selBasID) VALUES (" & _
               SQLStr("") & ", " & _
               SQLStr("Anonymous") & ", " & _
               SQLDate(vCreated) & ", " & _
               SQLVal(lID) & " " & _
               ")"
      gobjConn.Execute sSQL 
      Response.Redirect "XcIBAddSelectee.asp?ID=" & lID & "&AT=" & Server.URLEncode("" & vCreated) & "&EMAIL=" & Server.URLEncode(sEmail) & "&NAME=" & Server.URLEncode(sName)
   Else
      'sBaseName = "ASK"
      DoPageHeader
   	Response.Write("<CENTER>")
   	Response.Write("<TABLE WIDTH=""100%"" BORDER=""0"" CELLSPACING=""0"" CELLPADDING=""3"">") 
   	Response.Write("<TR  bgcolor=""" & gsLineColor & """><TD ></TD></TR>")
   	Response.Write("<TR bgcolor=""" & gsMainColor & """><TD ><FONT FACE =""" & sFont & """><BIG>" & sBaseName & gsInfoBaseName & "</BIG></TD></TR>")
   	Response.Write("<TR bgcolor=""" & gsLineColor & """><TD ></TD></TR>")
   	Response.Write("<TR><TD >")
   	ShowHTMLFile "XcIBAdded.htm"
   	Response.Write("</TD></TR>")
   
   	Response.Write("<TR bgcolor=""" & gsLineColor & """><TD ></TD></TR>")
   	Response.Write("<TR bgcolor=""" & gsMainColor & """><TD ><SMALL><CENTER>")
   	ShowNavigationBar
   	Response.Write("</CENTER></SMALL></TD></TR>")
   	Response.Write("<TR bgcolor=""" & gsLineColor & """><TD > </TD></TR></TABLE>")
      
      DoPageFooter
   End If
   CloseDBConn
End Sub


Sub AddForm
   OpenDBConn
   DoPageHeader
   
   sRootNav = ""
   'sBaseName = "Ask"
	Response.Write("<CENTER><FORM NAME=""ADDFORM"" METHOD=""POST"" ACTION=""add.asp""><INPUT TYPE=""HIDDEN"" NAME=""CMD"" VALUE=""ADD"">")
	Response.Write("<TABLE WIDTH=""100%"" BORDER=""0"" CELLSPACING=""0"" CELLPADDING=""3"">") 
   Response.Write("<TR><TD COLSPAN=""2""><SMALL>" & sRootNav & "</SMALL></TD></TR>")

	Response.Write("<TR  bgcolor=""" & gsLineColor & """><TD COLSPAN=""2""></TD></TR>")
	Response.Write("<TR bgcolor=""" & gsMainColor & """><TD COLSPAN=""2""><FONT FACE =""" & sFont & """><BIG>" & sBaseName & gsInfoBaseName & "</BIG></TD></TR>")
	Response.Write("<TR bgcolor=""" & gsLineColor & """><TD COLSPAN=""2""></TD></TR>")
	Response.Write("<TR><TD COLSPAN=""2"">")
	ShowHTMLFile "XcIBAdd.htm"
	Response.Write("</TD></TR>")
	If Len(Trim(sErr)) > 0 Then
	   Response.Write("<TR " & gsErrorColor & "><TD COLSPAN=""2""><SMALL>" & sErr & "</TD></TR>")
	End If
   Response.Write("<TR><TD><FONT SIZE=""2"" COLOR=""#000066"" FACE =""Arial, Helvetica, Geneva, Swiss, SunSans-Regular"">Your&nbsp;Name:&nbsp;</TD>")
   Response.Write("<TD><INPUT TYPE=""TEXT"" NAME=""NAME"" VALUE=""" & sName & """ SIZE=""25""></TD></TR>")
   Response.Write("<TR><TD><FONT SIZE=""2"" COLOR=""#000066"" FACE =""Arial, Helvetica, Geneva, Swiss, SunSans-Regular"">Your&nbsp;Email:&nbsp;</TD>")
   Response.Write("<TD><INPUT TYPE=""TEXT"" NAME=""EMAIL"" VALUE=""" & sEmail & """ SIZE=""25""></TD></TR>")
   Response.Write("<TR><TD><FONT SIZE=""2"" COLOR=""#000066"" FACE =""Arial, Helvetica, Geneva, Swiss, SunSans-Regular"">Question Title:&nbsp;</FONT></TD>")
   Response.Write("<TD><INPUT TYPE=""TEXT"" NAME=""TITLE"" VALUE=""" & sTitle & """ SIZE=""25""></TD></TR>")

   Response.Write("<TR><TD VALIGN=""TOP""><FONT SIZE=""2"" COLOR=""#000066"" FACE =""Arial, Helvetica, Geneva, Swiss, SunSans-Regular"">Category:&nbsp;</TD>")
   Response.Write("<TD><SMALL>")
   Response.Write("<SELECT NAME=""CATEGORY"" SIZE=""1""><OPTION VALUE=""0"" >* Pick A Category")
   lCatCount = 0
   sSQL = "SELECT * FROM tblIBCategories WHERE catParentID Is Null ORDER BY catDescription"
   Set rsCat = gobjConn.Execute(sSQL)
   Do While Not rsCat.Eof
      If EvalBool(rsCat.Fields("catRootable")) Then
         Response.Write("<OPTION VALUE=""" & rsCat.Fields("catID") & """ " & OutMatch(sCategory, "" & rsCat.Fields("catID"), "SELECTED", "") & ">" & rsCat.Fields("catDescription") ) 
      End If
      ShowSubCats  FVal(rsCat.Fields("catID")), "" & rsCat.Fields("catDescription") & " > " 
      lCatCount = lCatCount + 1
      rsCat.MoveNext
   Loop
   rsCat.Close
   Set rsCat = Nothing
   'If lCatCount = 0 Then
   '   Response.Write("<B>Error: No Categories Defined</B>")
   'End If
   Response.Write("</SELECT></SMALL></TD></TR>")
   Response.Write("<TR><TD VALIGN=""TOP""><FONT SIZE=""2"" COLOR=""#000066"" FACE =""Arial, Helvetica, Geneva, Swiss, SunSans-Regular"">Your&nbsp;Question:&nbsp;</FONT></TD>")
   Response.Write("<TD><TEXTAREA NAME=""MESSAGE"" COLS=""25"" ROWS=""8"">" & sMessage & "</TEXTAREA></TD></TR>")
   Response.Write("<TR><TD>&nbsp;</TD>")
   Response.Write("<TD><INPUT TYPE=""SUBMIT"" VALUE=""Submit Question"">&nbsp;</FORM></TD></TR>")

	Response.Write("<TR bgcolor=""" & gsLineColor & """><TD COLSPAN=""2""></TD></TR>")
	Response.Write("<TR bgcolor=""" & gsMainColor & """><TD COLSPAN=""2""><SMALL><CENTER>")
	ShowNavigationBar
	Response.Write("</CENTER></SMALL></TD></TR>")
	Response.Write("<TR bgcolor=""" & gsLineColor & """><TD COLSPAN=""2""> </TD></TR></TABLE>")
   DoPageFooter
   sCrLf = Chr(13) & Chr(10)
   Response.Write(sCrLf & "<SCRIPT LANGUAGE=""JavaScript"">" & sCrLf & "<!--" & sCrLf & "document.ADDFORM.NAME.focus();" & sCrLf & "//  -->" & sCrLf & "</SCRIPT>" & sCrLf )
   CloseDBConn
End Sub

Sub ShowSubCats( plCatID , psCatDesc)
   Dim sSQL
   Dim rsSubCat
   
   If plCatID > 0 Then
      sSQL = "SELECT * FROM tblIBCategories WHERE catParentID = " & SQLVal(plCatID) & " ORDER BY catDescription"
      Set rsSubCat = Server.CreateObject("ADODB.Recordset")
      rsSubCat.CursorLocation = adUseClient
      rsSubCat.Open sSQL, gobjConn, adOpenStatic, adLockReadOnly, adCmdText
      Do While Not rsSubCat.Eof
         If EvalBool(rsSubCat.Fields("catRootable")) Then
            Response.Write("<OPTION VALUE=""" & rsSubCat.Fields("catID") & """ " & OutMatch(sCategory, "" & rsSubCat.Fields("catID"), "SELECTED", "") & ">" & psCatDesc & rsSubCat.Fields("catDescription") )
         End If
         ShowSubCats FVal(rsSubCat.Fields("catID")), psCatDesc & rsSubCat.Fields("catDescription") & " > " 
         lCatCount = lCatCount + 1
         rsSubCat.MoveNext
      Loop
      rsSubCat.Close
      Set rsSubCat = Nothing
   End If
End Sub
%>